early-access version 2853

externals/vcpkg/ports/breakpad/CMakeLists.txt

@@ -0,0 +1,137 @@
+cmake_minimum_required(VERSION 3.8)
+project(breakpad CXX)
+
+set(CMAKE_CXX_STANDARD 11)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+
+add_definitions(
+    -DNOMINMAX
+    -DUNICODE
+    -DWIN32_LEAN_AND_MEAN
+    -D_CRT_SECURE_NO_WARNINGS
+    -D_CRT_SECURE_NO_DEPRECATE
+    -D_CRT_NONSTDC_NO_DEPRECATE
+)
+
+set(CMAKE_DEBUG_POSTFIX d)
+
+string(COMPARE EQUAL "${CMAKE_BUILD_TYPE}" "Release" DEFAULT_INSTALL_HEADERS)
+option(INSTALL_HEADERS "Install header files" ${DEFAULT_INSTALL_HEADERS})
+
+# libbreakpad target
+if(NOT CMAKE_SYSTEM_NAME STREQUAL Android)
+    file(GLOB_RECURSE LIBBREAKPAD_SOURCES src/processor/*.cc)
+    if(WIN32)
+        list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
+            "_unittest|synth_minidump|/tests|/testdata|/linux|/mac|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk")
+    elseif(APPLE)
+        list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
+            "_unittest|synth_minidump|/tests|/testdata|/linux|/windows|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk")
+    else()
+        list(FILTER LIBBREAKPAD_SOURCES EXCLUDE REGEX
+            "_unittest|synth_minidump|/tests|/testdata|/mac|/windows|/android|/solaris|microdump_stackwalk|minidump_dump|minidump_stackwalk")
+    endif()
+
+    find_library(LIBDISASM_LIB NAMES libdisasmd libdisasm)
+
+    add_library(libbreakpad ${LIBBREAKPAD_SOURCES})
+    target_link_libraries(libbreakpad PRIVATE ${LIBDISASM_LIB})
+
+    target_include_directories(libbreakpad
+        PUBLIC
+            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
+            $<INSTALL_INTERFACE:include>
+    )
+
+    set(TARGETS libbreakpad)
+endif()
+
+# libbreakpad_client target
+if(CMAKE_SYSTEM_NAME STREQUAL Android)
+    file(READ "android/google_breakpad/Android.mk" android_mk)
+    string(REGEX MATCHALL "src/[^\n]*\\.cc" LIBBREAKPAD_CLIENT_SOURCES "${android_mk}")
+else()
+    if(WIN32)
+        file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/windows/*.cc src/common/windows/*.cc)
+        include_directories("$ENV{VSINSTALLDIR}/DIA SDK/include")
+    elseif(APPLE)
+        add_definitions(-DHAVE_MACH_O_NLIST_H)
+        file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/mac/*.cc src/common/mac/*.cc)
+        list(APPEND LIBBREAKPAD_CLIENT_SOURCES src/common/mac/MachIPC.mm)
+    else()
+        add_definitions(-DHAVE_A_OUT_H)
+        file(GLOB_RECURSE LIBBREAKPAD_CLIENT_SOURCES src/client/linux/*.cc src/common/linux/*.cc)
+    endif()
+    file(GLOB LIBBREAKPAD_COMMON_SOURCES src/common/*.cc src/common/*.c src/client/*.cc)
+    list(APPEND LIBBREAKPAD_CLIENT_SOURCES ${LIBBREAKPAD_COMMON_SOURCES})
+endif()
+list(FILTER LIBBREAKPAD_CLIENT_SOURCES EXCLUDE REGEX "/sender|/tests|/unittests|/testcases|_unittest|_test")
+if(WIN32)
+    list(FILTER LIBBREAKPAD_CLIENT_SOURCES EXCLUDE REGEX "language.cc|path_helper.cc|stabs_to_module.cc|stabs_reader.cc|minidump_file_writer.cc")
+elseif(NOT APPLE)
+    try_compile(HAVE_GETCONTEXT ${CMAKE_BINARY_DIR}/check_getcontext ${CMAKE_CURRENT_LIST_DIR}/check_getcontext.cc OUTPUT_VARIABLE BUILD_OUT)
+    if (NOT HAVE_GETCONTEXT)
+        enable_language(ASM)
+        list(APPEND LIBBREAKPAD_CLIENT_SOURCES src/common/linux/breakpad_getcontext.S)
+    endif()
+endif()
+
+add_library(libbreakpad_client ${LIBBREAKPAD_CLIENT_SOURCES})
+if(WIN32)
+    target_link_libraries(libbreakpad_client PRIVATE wininet.lib)
+elseif(APPLE)
+    find_library(CoreFoundation_FRAMEWORK CoreFoundation)
+    target_link_libraries(libbreakpad_client PRIVATE ${CoreFoundation_FRAMEWORK})
+else()
+    find_library(PTHREAD_LIBRARIES pthread)
+    if(PTHREAD_LIBRARIES)
+        target_link_libraries(libbreakpad_client PRIVATE ${PTHREAD_LIBRARIES})
+    endif()
+    if (HAVE_GETCONTEXT)
+        target_compile_definitions(libbreakpad_client PRIVATE HAVE_GETCONTEXT=1)
+    endif()
+endif()
+
+target_include_directories(libbreakpad_client
+    PUBLIC
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
+        $<INSTALL_INTERFACE:include>
+)
+list(APPEND TARGETS libbreakpad_client)
+
+# installation
+install(TARGETS ${TARGETS} EXPORT unofficial-breakpad-targets
+    RUNTIME DESTINATION bin
+    LIBRARY DESTINATION lib
+    ARCHIVE DESTINATION lib
+)
+
+if(INSTALL_HEADERS)
+    if(WIN32)
+        set(HEADER_EXCLUDE_REGEX "/apple|/ios|/linux|/mac|/solaris|/android|/dwarf|/tests|/testdata|/unittests")
+    elseif(APPLE)
+        set(HEADER_EXCLUDE_REGEX "/apple|/ios|/linux|/windows|/solaris|/android|/dwarf|/tests|/testdata|/unittests|/sender|/testapp|/*proj|/gcov")
+    else()
+        set(HEADER_EXCLUDE_REGEX "/apple|/ios|/windows|/mac|/solaris|/android|/dwarf|/tests|/testdata|/unittests")
+        install(
+            DIRECTORY src/third_party/lss
+            DESTINATION include/third_party
+            FILES_MATCHING PATTERN "*.h"
+            REGEX "${HEADER_EXCLUDE_REGEX}" EXCLUDE
+        )
+    endif()
+    install(
+        DIRECTORY src/client src/common src/google_breakpad
+        DESTINATION include/
+        FILES_MATCHING
+        PATTERN "*.h"
+        REGEX ${HEADER_EXCLUDE_REGEX} EXCLUDE
+    )
+endif()
+
+install(
+    EXPORT unofficial-breakpad-targets
+    FILE unofficial-breakpad-config.cmake
+    NAMESPACE unofficial::breakpad::
+    DESTINATION share/unofficial-breakpad
+)

externals/vcpkg/ports/breakpad/check_getcontext.cc

@@ -0,0 +1,9 @@
+#include <ucontext.h>
+#include <cstddef>
+
+int main() {
+    ucontext_t context;
+    getcontext(&context);
+
+    return 0;
+}

externals/vcpkg/ports/breakpad/fix-unique_ptr.patch

@@ -0,0 +1,13 @@
+diff --git a/src/common/windows/pe_util.cc b/src/common/windows/pe_util.cc
+index 9f9e8fa..d912635 100644
+--- a/src/common/windows/pe_util.cc
++++ b/src/common/windows/pe_util.cc
+@@ -28,7 +28,7 @@
+ // OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+ 
+ #include "pe_util.h"
+-
++#include <memory>
+ #include <windows.h>
+ #include <winnt.h>
+ #include <atlbase.h>

externals/vcpkg/ports/breakpad/fix-unordered_map.patch

@@ -0,0 +1,14 @@
+diff --git a/src/common/unordered.h b/src/common/unordered.h
+index c9cbd58..7743eda 100644
+--- a/src/common/unordered.h
++++ b/src/common/unordered.h
+@@ -46,7 +46,8 @@ struct unordered_map : public __gnu_cxx::hash_map<T, U, H> {};
+ template <class T, class H = __gnu_cxx::hash<T> >
+ struct unordered_set : public __gnu_cxx::hash_set<T, H> {};
+ 
+-#elif defined(_LIBCPP_VERSION)  // c++11
++#elif (__cplusplus >= 201103L) || defined(_LIBCPP_VERSION) || \
++    (defined(_MSC_VER) && (_MSC_VER >= 1800))  // c++11
+ #include <unordered_map>
+ #include <unordered_set>
+ using std::unordered_map;

externals/vcpkg/ports/breakpad/portfile.cmake

@@ -0,0 +1,40 @@
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO google/breakpad
+    REF 9c4671f2e3a63c0f155d9b2511192d0b5fa7f760 # accessed on 2020-09-14
+    SHA512 4c9ed9b675a772f9a6a84692865381130901820cb395b725511e7a9e2cbf4aaa5212a9ef5f87086baf58bb9d729082232b564bd827a205f87b5c1ffc1c53892a
+    HEAD_REF master
+    PATCHES
+        fix-unique_ptr.patch
+        fix-unordered_map.patch
+)
+
+if(VCPKG_HOST_IS_LINUX OR VCPKG_TARGET_IS_LINUX OR VCPKG_TARGET_IS_ANDROID)
+    vcpkg_from_git(
+        OUT_SOURCE_PATH LSS_SOURCE_PATH
+        URL https://chromium.googlesource.com/linux-syscall-support
+        REF 7bde79cc274d06451bf65ae82c012a5d3e476b5a
+    )
+    
+    file(RENAME "${LSS_SOURCE_PATH}" "${SOURCE_PATH}/src/third_party/lss")
+endif()
+
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt" "${CMAKE_CURRENT_LIST_DIR}/check_getcontext.cc" DESTINATION "${SOURCE_PATH}")
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        -DINSTALL_HEADERS=ON
+)
+
+vcpkg_cmake_install()
+   file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+   file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/include/client/linux/data" "${CURRENT_PACKAGES_DIR}/include/client/linux/sender")
+
+vcpkg_cmake_config_fixup(PACKAGE_NAME unofficial-breakpad CONFIG_PATH share/unofficial-breakpad)
+
+vcpkg_copy_pdbs()
+
+file(INSTALL "${SOURCE_PATH}/LICENSE" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)

externals/vcpkg/ports/breakpad/vcpkg.json

@@ -0,0 +1,19 @@
+{
+  "name": "breakpad",
+  "version-date": "2020-09-14",
+  "port-version": 5,
+  "description": "a set of client and server components which implement a crash-reporting system.",
+  "homepage": "https://github.com/google/breakpad",
+  "supports": "!uwp",
+  "dependencies": [
+    "libdisasm",
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ]
+}