early-access version 2853

externals/vcpkg/ports/imgui/CMakeLists.txt

@@ -0,0 +1,228 @@
+cmake_minimum_required(VERSION 3.16)
+project(imgui CXX)
+
+set(CMAKE_DEBUG_POSTFIX d)
+
+if(APPLE)
+    set(CMAKE_CXX_STANDARD 11)
+    enable_language(OBJCXX)
+endif()
+
+add_library(${PROJECT_NAME} "")
+add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS ${PROJECT_NAME})
+target_include_directories(
+    ${PROJECT_NAME}
+    PUBLIC
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+        $<INSTALL_INTERFACE:include>
+)
+
+target_sources(
+    ${PROJECT_NAME}
+    PRIVATE
+        ${CMAKE_CURRENT_SOURCE_DIR}/imgui.cpp
+        ${CMAKE_CURRENT_SOURCE_DIR}/imgui_demo.cpp
+        ${CMAKE_CURRENT_SOURCE_DIR}/imgui_draw.cpp
+        ${CMAKE_CURRENT_SOURCE_DIR}/imgui_tables.cpp
+        ${CMAKE_CURRENT_SOURCE_DIR}/imgui_widgets.cpp
+        ${CMAKE_CURRENT_SOURCE_DIR}/misc/cpp/imgui_stdlib.cpp
+)
+
+if(IMGUI_BUILD_ALLEGRO5_BINDING)
+    find_path(ALLEGRO5_INCLUDE_DIRS allegro5/allegro.h)
+    target_include_directories(${PROJECT_NAME} PRIVATE ${ALLEGRO5_INCLUDE_DIRS})
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_allegro5.cpp)
+endif()
+
+if(IMGUI_BUILD_DX9_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_dx9.cpp)
+endif()
+
+if(IMGUI_BUILD_DX10_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_dx10.cpp)
+endif()
+
+if(IMGUI_BUILD_DX11_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_dx11.cpp)
+endif()
+
+if(IMGUI_BUILD_DX12_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_dx12.cpp)
+endif()
+
+if(IMGUI_BUILD_GLFW_BINDING)
+    find_package(glfw3 CONFIG REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC glfw)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_glfw.cpp)
+endif()
+
+if(IMGUI_BUILD_GLUT_BINDING)
+    find_package(GLUT REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC GLUT::GLUT)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_glut.cpp)
+endif()
+
+if(IMGUI_BUILD_METAL_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_metal.mm)
+    set_source_files_properties(${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_metal.mm PROPERTIES COMPILE_FLAGS -fobjc-weak)
+endif()
+
+if(IMGUI_BUILD_OPENGL2_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_opengl2.cpp)
+endif()
+
+if(IMGUI_BUILD_OPENGL3_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_opengl3.cpp)
+endif()
+
+if(IMGUI_BUILD_OSX_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_osx.mm)
+endif()
+
+if(IMGUI_BUILD_SDL2_BINDING)
+    find_package(SDL2 CONFIG REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC SDL2::SDL2)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_sdl.cpp)
+endif()
+
+if(IMGUI_BUILD_SDL2_RENDERER_BINDING)
+    find_package(SDL2 CONFIG REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC SDL2::SDL2)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_sdlrenderer.cpp)
+endif()
+
+if(IMGUI_BUILD_VULKAN_BINDING)
+    find_package(Vulkan REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC Vulkan::Vulkan)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_vulkan.cpp)
+endif()
+
+if(IMGUI_BUILD_WIN32_BINDING)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_win32.cpp)
+endif()
+
+if(IMGUI_FREETYPE)
+    find_package(freetype CONFIG REQUIRED)
+    target_link_libraries(${PROJECT_NAME} PUBLIC freetype)
+    target_sources(${PROJECT_NAME} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/misc/freetype/imgui_freetype.cpp)
+    target_compile_definitions(${PROJECT_NAME} PUBLIC IMGUI_ENABLE_FREETYPE)
+endif()
+
+if(IMGUI_USE_WCHAR32)
+    target_compile_definitions(${PROJECT_NAME} PUBLIC IMGUI_USE_WCHAR32)
+endif()
+
+list(REMOVE_DUPLICATES BINDINGS_SOURCES)
+
+install(
+    TARGETS ${PROJECT_NAME}
+    EXPORT ${PROJECT_NAME}_target
+    ARCHIVE DESTINATION lib
+    LIBRARY DESTINATION lib
+    RUNTIME DESTINATION bin
+)
+
+foreach(BINDING_TARGET ${BINDING_TARGETS})
+    install(
+        TARGETS ${BINDING_TARGET}
+        EXPORT ${PROJECT_NAME}_target
+        ARCHIVE DESTINATION lib
+        LIBRARY DESTINATION lib
+        RUNTIME DESTINATION bin
+    )
+endforeach()
+
+if(NOT IMGUI_SKIP_HEADERS)
+    install(FILES
+        ${CMAKE_CURRENT_SOURCE_DIR}/imgui.h
+        ${CMAKE_CURRENT_SOURCE_DIR}/imconfig.h
+        ${CMAKE_CURRENT_SOURCE_DIR}/imgui_internal.h
+        ${CMAKE_CURRENT_SOURCE_DIR}/imstb_textedit.h
+        ${CMAKE_CURRENT_SOURCE_DIR}/imstb_rectpack.h
+        ${CMAKE_CURRENT_SOURCE_DIR}/imstb_truetype.h
+        ${CMAKE_CURRENT_SOURCE_DIR}/misc/cpp/imgui_stdlib.h
+        DESTINATION include
+    )
+
+    if(IMGUI_BUILD_ALLEGRO5_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_allegro5.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_DX9_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_dx9.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_DX10_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_dx10.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_DX11_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_dx11.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_DX12_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_dx12.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_GLFW_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_glfw.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_GLUT_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_glut.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_METAL_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_metal.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_OPENGL2_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_opengl2.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_OPENGL3_BINDING)
+        install(
+            FILES
+                ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_opengl3.h
+                ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_opengl3_loader.h
+            DESTINATION
+                include
+        )
+    endif()
+
+    if(IMGUI_BUILD_OSX_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_osx.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_SDL2_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_sdl.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_SDL2_RENDERER_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_sdlrenderer.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_VULKAN_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_vulkan.h DESTINATION include)
+    endif()
+
+    if(IMGUI_BUILD_WIN32_BINDING)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/backends/imgui_impl_win32.h DESTINATION include)
+    endif()
+
+    if(IMGUI_FREETYPE)
+        install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/misc/freetype/imgui_freetype.h DESTINATION include)
+    endif()
+endif()
+
+include(CMakePackageConfigHelpers)
+configure_package_config_file(imgui-config.cmake.in imgui-config.cmake INSTALL_DESTINATION share/imgui)
+
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/imgui-config.cmake DESTINATION share/imgui)
+
+install(
+    EXPORT ${PROJECT_NAME}_target
+    NAMESPACE ${PROJECT_NAME}::
+    FILE ${PROJECT_NAME}-targets.cmake
+    DESTINATION share/${PROJECT_NAME}
+)

externals/vcpkg/ports/imgui/imgui-config.cmake.in

@@ -0,0 +1,27 @@
+cmake_policy(SET CMP0012 NEW)
+
+@PACKAGE_INIT@
+
+include(CMakeFindDependencyMacro)
+
+if (@IMGUI_BUILD_GLFW_BINDING@)
+    find_dependency(glfw3 CONFIG)
+endif()
+
+if (@IMGUI_BUILD_GLUT_BINDING@)
+    find_dependency(GLUT)
+endif()
+
+if (@IMGUI_BUILD_SDL2_BINDING@ OR @IMGUI_BUILD_SDL2_RENDERER_BINDING@)
+    find_dependency(SDL2 CONFIG)
+endif()
+
+if (@IMGUI_BUILD_VULKAN_BINDING@)
+    find_dependency(Vulkan)
+endif()
+
+if (@IMGUI_FREETYPE@)
+    find_dependency(freetype CONFIG)
+endif()
+
+include("${CMAKE_CURRENT_LIST_DIR}/imgui-targets.cmake")

externals/vcpkg/ports/imgui/portfile.cmake

@@ -0,0 +1,78 @@
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+if ("docking-experimental" IN_LIST FEATURES)
+    vcpkg_from_github(
+       OUT_SOURCE_PATH SOURCE_PATH
+       REPO ocornut/imgui
+       REF 1ee252772ae9c0a971d06257bb5c89f628fa696a
+       SHA512 942cd8e39f490c15d90b6feb6f919ebeab8f6f8f9aacfcbf552daef24b0f7e637ad5f630767a52fd9993d84a80b5954c7b05f7400a9f96b6b739cf5680368119
+       HEAD_REF docking
+       )
+else()
+    vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO ocornut/imgui
+    REF v1.87
+    SHA512 3255b06698ab9c8951953e1e0b6d160d64adfa4c011b21a4288547292a7f8fff586875faf9dae0677818bde65bd7e98da92f16f6beb1e6a66aa835edf32e8ce2
+    HEAD_REF master
+    )
+endif()
+
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/imgui-config.cmake.in" DESTINATION "${SOURCE_PATH}")
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt" DESTINATION "${SOURCE_PATH}")
+
+vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
+    FEATURES 
+    allegro5-binding            IMGUI_BUILD_ALLEGRO5_BINDING
+    dx9-binding                 IMGUI_BUILD_DX9_BINDING
+    dx10-binding                IMGUI_BUILD_DX10_BINDING
+    dx11-binding                IMGUI_BUILD_DX11_BINDING
+    dx12-binding                IMGUI_BUILD_DX12_BINDING
+    glfw-binding                IMGUI_BUILD_GLFW_BINDING
+    glut-binding                IMGUI_BUILD_GLUT_BINDING
+    metal-binding               IMGUI_BUILD_METAL_BINDING
+    opengl2-binding             IMGUI_BUILD_OPENGL2_BINDING
+    opengl3-binding             IMGUI_BUILD_OPENGL3_BINDING
+    osx-binding                 IMGUI_BUILD_OSX_BINDING
+    sdl2-binding                IMGUI_BUILD_SDL2_BINDING
+    sdl2-renderer-binding       IMGUI_BUILD_SDL2_RENDERER_BINDING
+    vulkan-binding              IMGUI_BUILD_VULKAN_BINDING
+    win32-binding               IMGUI_BUILD_WIN32_BINDING
+    freetype                    IMGUI_FREETYPE
+    wchar32                     IMGUI_USE_WCHAR32
+)
+
+if ("libigl-imgui" IN_LIST FEATURES)
+    vcpkg_download_distfile(
+        IMGUI_FONTS_DROID_SANS_H
+        URLS
+            https://raw.githubusercontent.com/libigl/libigl-imgui/c3efb9b62780f55f9bba34561f79a3087e057fc0/imgui_fonts_droid_sans.h
+        FILENAME "imgui_fonts_droid_sans.h"
+        SHA512
+            abe9250c9a5989e0a3f2285bbcc83696ff8e38c1f5657c358e6fe616ff792d3c6e5ff2fa23c2eeae7d7b307392e0dc798a95d14f6d10f8e9bfbd7768d36d8b31
+    )
+
+    file(INSTALL "${IMGUI_FONTS_DROID_SANS_H}" DESTINATION "${CURRENT_PACKAGES_DIR}/include")
+endif()
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        ${FEATURE_OPTIONS}
+    OPTIONS_DEBUG
+        -DIMGUI_SKIP_HEADERS=ON
+)
+
+vcpkg_cmake_install()
+
+if ("freetype" IN_LIST FEATURES)
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/imconfig.h" "//#define IMGUI_ENABLE_FREETYPE" "#define IMGUI_ENABLE_FREETYPE")
+endif()
+if ("wchar32" IN_LIST FEATURES)
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/imconfig.h" "//#define IMGUI_USE_WCHAR32" "#define IMGUI_USE_WCHAR32")
+endif()
+
+vcpkg_copy_pdbs()
+vcpkg_cmake_config_fixup()
+
+file(INSTALL "${SOURCE_PATH}/LICENSE.txt" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)

externals/vcpkg/ports/imgui/vcpkg.json

@@ -0,0 +1,104 @@
+{
+  "name": "imgui",
+  "version": "1.87",
+  "port-version": 1,
+  "description": "Bloat-free Immediate Mode Graphical User interface for C++ with minimal dependencies.",
+  "homepage": "https://github.com/ocornut/imgui",
+  "license": "MIT",
+  "dependencies": [
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ],
+  "features": {
+    "allegro5-binding": {
+      "description": "Make available Allegro5 binding",
+      "dependencies": [
+        "allegro5"
+      ]
+    },
+    "docking-experimental": {
+      "description": "Build with docking support"
+    },
+    "dx10-binding": {
+      "description": "Make available DirectX10 binding",
+      "supports": "windows & !uwp"
+    },
+    "dx11-binding": {
+      "description": "Make available DirectX11 binding",
+      "supports": "windows & !uwp"
+    },
+    "dx12-binding": {
+      "description": "Make available DirectX12 binding",
+      "supports": "!x86 & windows & !uwp"
+    },
+    "dx9-binding": {
+      "description": "Make available DirectX9 binding",
+      "supports": "windows & !uwp"
+    },
+    "freetype": {
+      "description": "Build font atlases using FreeType instead of stb_truetype",
+      "dependencies": [
+        "freetype"
+      ]
+    },
+    "glfw-binding": {
+      "description": "Make available GLFW binding",
+      "dependencies": [
+        "glfw3"
+      ]
+    },
+    "glut-binding": {
+      "description": "Make available Glut binding",
+      "dependencies": [
+        "freeglut"
+      ]
+    },
+    "libigl-imgui": {
+      "description": "Install the libigl-imgui headers"
+    },
+    "metal-binding": {
+      "description": "Make available Metal binding",
+      "supports": "osx"
+    },
+    "opengl2-binding": {
+      "description": "Make available OpenGL (legacy) binding"
+    },
+    "opengl3-binding": {
+      "description": "Make available OpenGL3/ES/ES2 (modern) binding"
+    },
+    "osx-binding": {
+      "description": "Make available OSX binding",
+      "supports": "osx"
+    },
+    "sdl2-binding": {
+      "description": "Make available SDL2 binding",
+      "dependencies": [
+        "sdl2"
+      ]
+    },
+    "sdl2-renderer-binding": {
+      "description": "Make available SDL2 Renderer binding",
+      "dependencies": [
+        "sdl2"
+      ]
+    },
+    "vulkan-binding": {
+      "description": "Make available Vulkan binding",
+      "dependencies": [
+        "vulkan"
+      ]
+    },
+    "wchar32": {
+      "description": "Use WCHAR32 instead of WCHAR16"
+    },
+    "win32-binding": {
+      "description": "Make available Win32 binding"
+    }
+  }
+}