early-access version 2853

externals/vcpkg/ports/libuv/CMakeLists.txt

@@ -0,0 +1,83 @@
+cmake_minimum_required(VERSION 3.5)
+project(libuv C)
+
+find_package(Threads REQUIRED)
+
+file(GLOB UV_SOURCES_COMMON src/*.c)
+
+file(GLOB UV_SOURCES_UNIX
+    src/unix/async.c
+    src/unix/core.c
+    src/unix/dl.c
+    src/unix/fs.c
+    src/unix/getaddrinfo.c
+    src/unix/getnameinfo.c
+    src/unix/loop.c
+    src/unix/loop-watcher.c
+    src/unix/pipe.c
+    src/unix/poll.c
+    src/unix/process.c
+    src/unix/signal.c
+    src/unix/stream.c
+    src/unix/tcp.c
+    src/unix/thread.c
+    src/unix/tty.c
+    src/unix/udp.c
+)
+file(GLOB UV_SOURCES_LINUX
+    src/unix/proctitle.c
+    src/unix/linux-core.c
+    src/unix/linux-inotify.c
+    src/unix/linux-syscalls.c
+    src/unix/procfs-exepath.c
+    src/unix/sysinfo-loadavg.c
+    src/unix/sysinfo-memory.c
+    src/unix/epoll.c
+)
+file(GLOB UV_SOURCES_DARWIN
+    src/unix/proctitle.c
+    src/unix/darwin.c
+    src/unix/fsevents.c
+    src/unix/darwin-proctitle.c
+    src/unix/bsd-ifaddrs.c
+    src/unix/kqueue.c
+)
+file(GLOB UV_SOURCES_FREEBSD
+    src/unix/freebsd.c
+    src/unix/posix-hrtime.c
+    src/unix/bsd-proctitle.c
+    src/unix/bsd-ifaddrs.c
+    src/unix/kqueue.c
+)
+file(GLOB UV_SOURCES_WIN src/win/*.c)
+
+if(CMAKE_SYSTEM_NAME STREQUAL "Windows" OR CMAKE_SYSTEM_NAME STREQUAL "WindowsStore")
+    add_library(libuv ${UV_SOURCES_COMMON} ${UV_SOURCES_WIN})
+    target_compile_definitions(libuv PRIVATE WIN32_LEAN_AND_MEAN "_WIN32_WINNT=0x0600")
+    target_link_libraries(libuv PRIVATE iphlpapi psapi shell32 userenv ws2_32)
+elseif(APPLE)
+    add_library(libuv ${UV_SOURCES_COMMON} ${UV_SOURCES_UNIX} ${UV_SOURCES_DARWIN})
+elseif(CMAKE_SYSTEM_NAME STREQUAL "FreeBSD")
+    add_library(libuv ${UV_SOURCES_COMMON} ${UV_SOURCES_UNIX} ${UV_SOURCES_FREEBSD})
+else() # Assume some Linux variant
+    add_library(libuv ${UV_SOURCES_COMMON} ${UV_SOURCES_UNIX} ${UV_SOURCES_LINUX})
+endif()
+
+target_link_libraries(libuv PRIVATE Threads::Threads)
+target_include_directories(libuv PUBLIC $<INSTALL_INTERFACE:include> $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include> $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>)
+set_target_properties(libuv PROPERTIES DEFINE_SYMBOL BUILDING_UV_SHARED)
+
+if(NOT UV_SKIP_HEADERS)
+    install(
+        DIRECTORY include/
+        DESTINATION include
+    )
+endif()
+
+install(TARGETS libuv
+    EXPORT libuv
+    RUNTIME DESTINATION bin
+    ARCHIVE DESTINATION lib
+    LIBRARY DESTINATION lib
+)
+install(EXPORT libuv FILE unofficial-libuv-targets.cmake NAMESPACE unofficial::libuv:: DESTINATION share/unofficial-libuv)

externals/vcpkg/ports/libuv/portfile.cmake

@@ -0,0 +1,39 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO libuv/libuv
+    REF v1.43.0
+    SHA512 66ee11f8f6fc1313c432858572789cf67acd6364b29a06c73323ab20626e2d6e3d3dcea748cf5d9d4368b40ad7fe0d5fd35e9369c22e531db523703f005248d3
+    HEAD_REF v1.x
+)
+
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt" DESTINATION "${SOURCE_PATH}")
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS_DEBUG
+        -DUV_SKIP_HEADERS=ON
+)
+
+vcpkg_cmake_install()
+vcpkg_cmake_config_fixup(PACKAGE_NAME unofficial-libuv CONFIG_PATH share/unofficial-libuv)
+vcpkg_copy_pdbs()
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
+
+configure_file(
+    "${CMAKE_CURRENT_LIST_DIR}/unofficial-libuv-config.in.cmake"
+    "${CURRENT_PACKAGES_DIR}/share/unofficial-libuv/unofficial-libuv-config.cmake"
+    @ONLY
+)
+
+file(READ "${CURRENT_PACKAGES_DIR}/include/uv.h" UV_H)
+if(VCPKG_LIBRARY_LINKAGE STREQUAL "dynamic")
+    string(REPLACE "defined(USING_UV_SHARED)" "1" UV_H "${UV_H}")
+else()
+    string(REPLACE "defined(USING_UV_SHARED)" "0" UV_H "${UV_H}")
+    configure_file("${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake" "${CURRENT_PACKAGES_DIR}/share/${PORT}/vcpkg-cmake-wrapper.cmake" @ONLY)
+endif()
+file(WRITE "${CURRENT_PACKAGES_DIR}/include/uv.h" "${UV_H}")
+
+file(INSTALL "${SOURCE_PATH}/LICENSE" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
+

externals/vcpkg/ports/libuv/unofficial-libuv-config.in.cmake

@@ -0,0 +1,7 @@
+
+if("@VCPKG_LIBRARY_LINKAGE@" STREQUAL "static")
+    include(CMakeFindDependencyMacro)
+    find_dependency(Threads)
+endif()
+
+include(${CMAKE_CURRENT_LIST_DIR}/unofficial-libuv-targets.cmake)

externals/vcpkg/ports/libuv/vcpkg-cmake-wrapper.cmake

@@ -0,0 +1,16 @@
+_find_package(${ARGS})
+
+if(WIN32)
+    list(APPEND LibUV_LIBRARIES iphlpapi psapi shell32 userenv ws2_32)
+    if(TARGET LibUV::LibUV)
+        set_property(TARGET LibUV::LibUV APPEND PROPERTY INTERFACE_LINK_LIBRARIES iphlpapi psapi shell32 userenv ws2_32)
+    endif()
+endif()
+include(CMakeFindDependencyMacro)
+find_dependency(Threads)
+list(APPEND LibUV_LIBRARIES Threads::Threads)
+if(TARGET LibUV::LibUV)
+    set_property(TARGET LibUV::LibUV APPEND PROPERTY INTERFACE_LINK_LIBRARIES Threads::Threads)
+endif()
+
+

externals/vcpkg/ports/libuv/vcpkg.json

@@ -0,0 +1,16 @@
+{
+  "name": "libuv",
+  "version-semver": "1.43.0",
+  "description": "libuv is a multi-platform support library with a focus on asynchronous I/O.",
+  "homepage": "https://github.com/libuv/libuv",
+  "dependencies": [
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ]
+}