early-access version 2853

externals/vcpkg/ports/nativefiledialog/CMakeLists.txt

@@ -0,0 +1,69 @@
+cmake_minimum_required(VERSION 3.14)
+
+project(nfd LANGUAGES C)
+
+include(GNUInstallDirs)
+
+option(NFD_GTK_BACKEND "Using GTK backend" ON)
+
+file(GLOB nfd_sources
+    "${PROJECT_SOURCE_DIR}/src/*.h"
+    "${PROJECT_SOURCE_DIR}/src/include/*.h"
+    "${PROJECT_SOURCE_DIR}/src/nfd_common.c"
+)
+
+if (WIN32)
+    enable_language(CXX)
+    list(APPEND nfd_sources "${PROJECT_SOURCE_DIR}/src/nfd_win.cpp")
+elseif (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
+    if (NFD_GTK_BACKEND)
+        find_package(GTK3 QUIET)
+        if (GTK3_FOUND)
+            list(APPEND nfd_sources "${PROJECT_SOURCE_DIR}/src/nfd_gtk.c")
+        else ()
+            list(APPEND nfd_sources "${PROJECT_SOURCE_DIR}/src/nfd_zenity.c")
+        endif ()
+    else ()
+        list(APPEND nfd_sources "${PROJECT_SOURCE_DIR}/src/nfd_zenity.c")
+    endif ()
+elseif (${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
+    list(APPEND nfd_sources "${PROJECT_SOURCE_DIR}/src/nfd_cocoa.m")
+endif ()
+
+add_library(nfd ${nfd_sources})
+
+set_target_properties(
+    nfd
+    PROPERTIES
+        DEBUG_POSTFIX "_d"
+        PUBLIC_HEADER ${CMAKE_CURRENT_LIST_DIR}/src/include/nfd.h
+)
+
+target_compile_definitions(
+    nfd
+    PRIVATE
+        $<$<C_COMPILER_ID:MSVC>:_CRT_SECURE_NO_WARNINGS>
+)
+
+target_include_directories(nfd PRIVATE
+        $<BUILD_INTERFACE:
+			${CMAKE_CURRENT_LIST_DIR}/src 
+			${CMAKE_CURRENT_LIST_DIR}/src/include
+		>)
+		
+target_include_directories(nfd INTERFACE 
+		$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
+
+if (GTK3_FOUND)
+    target_include_directories(nfd PUBLIC ${GTK3_INCLUDE_DIRS})
+    target_link_libraries(nfd PUBLIC ${GTK3_LIBRARIES})
+endif ()
+
+install(TARGETS nfd EXPORT unofficial-nativefiledialog-config)
+
+install(
+    EXPORT unofficial-nativefiledialog-config
+    NAMESPACE unofficial::nativefiledialog::
+    DESTINATION share/unofficial-nativefiledialog
+    PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
+)

externals/vcpkg/ports/nativefiledialog/portfile.cmake

@@ -0,0 +1,37 @@
+if(VCPKG_CMAKE_SYSTEM_NAME STREQUAL "WindowsStore")
+    message(FATAL_ERROR "${PORT} does not currently support UWP")
+endif()
+
+vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO mlabbe/nativefiledialog
+    REF 67345b80ebb429ecc2aeda94c478b3bcc5f7888e
+    SHA512 55edb3730b718b18d4fee7ec9bb479794d0e193ff13f05f26cbcf9ff44c43adb93e228ed7fd708e30c08476366f098bf69139031a84f5e4d6a85eba096fe4654
+    HEAD_REF master
+)
+
+file(COPY ${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt DESTINATION ${SOURCE_PATH})
+
+vcpkg_check_features(
+    OUT_FEATURE_OPTIONS FEATURE_OPTIONS
+    INVERTED_FEATURES "zenity" NFD_GTK_BACKEND
+)
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        ${FEATURE_OPTIONS}
+)
+
+vcpkg_cmake_install()
+
+vcpkg_cmake_config_fixup(PACKAGE_NAME unofficial-${PORT} CONFIG_PATH share/unofficial-${PORT})
+vcpkg_fixup_pkgconfig()
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
+
+# Handle copyright
+configure_file("${SOURCE_PATH}/LICENSE" "${CURRENT_PACKAGES_DIR}/share/${PORT}/copyright" COPYONLY)

externals/vcpkg/ports/nativefiledialog/vcpkg.json

@@ -0,0 +1,22 @@
+{
+  "name": "nativefiledialog",
+  "version-date": "2022-01-20",
+  "description": "A tiny, neat C library that portably invokes native file open and save dialogs",
+  "homepage": "https://github.com/mlabbe/nativefiledialog",
+  "supports": "!uwp",
+  "dependencies": [
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ],
+  "features": {
+    "zenity": {
+      "description": "Using Zenity backend on Linux"
+    }
+  }
+}