early-access version 2853

externals/vcpkg/ports/nccl/FindNCCL.cmake

@@ -0,0 +1,97 @@
+# Find the nccl libraries
+#
+# The following variables are optionally searched for defaults
+#  NCCL_ROOT: Base directory where all NCCL components are found
+#  NCCL_INCLUDE_DIR: Directory where NCCL header is found
+#  NCCL_LIB_DIR: Directory where NCCL library is found
+#
+# The following are set after configuration is done:
+#  NCCL_FOUND
+#  NCCL_INCLUDE_DIRS
+#  NCCL_LIBRARIES
+#
+# Adapted from https://github.com/pytorch/pytorch/blob/master/cmake/Modules/FindNCCL.cmake
+
+set(NCCL_INCLUDE_DIR $ENV{NCCL_INCLUDE_DIR} CACHE PATH "Folder contains NVIDIA NCCL headers")
+set(NCCL_LIB_DIR $ENV{NCCL_LIB_DIR} CACHE PATH "Folder contains NVIDIA NCCL libraries")
+set(_NCCL_VERSION $ENV{NCCL_VERSION} CACHE STRING "Version of NCCL to build with")
+
+list(APPEND NCCL_ROOT $ENV{NCCL_ROOT_DIR} ${CUDA_TOOLKIT_ROOT_DIR})
+# Compatible layer for CMake <3.12. NCCL_ROOT will be accounted in for searching paths and libraries for CMake >=3.12.
+list(APPEND CMAKE_PREFIX_PATH ${NCCL_ROOT})
+
+find_path(NCCL_INCLUDE_DIRS
+  NAMES nccl.h
+  HINTS
+  ${NCCL_INCLUDE_DIR}
+  $ENV{CUDNN_ROOT_DIR}
+  $ENV{CUDA_PATH}
+  $ENV{CUDNN_ROOT_DIR}
+  $ENV{CUDA_TOOLKIT_ROOT_DIR}
+  $ENV{NCCL}
+  /usr/include
+  PATH_SUFFIXES
+  include
+)
+
+if (USE_STATIC_NCCL)
+  MESSAGE(STATUS "USE_STATIC_NCCL is set. Linking with static NCCL library.")
+  SET(NCCL_LIBNAME "nccl_static")
+  if (_NCCL_VERSION)  # Prefer the versioned library if a specific NCCL version is specified
+    set(CMAKE_FIND_LIBRARY_SUFFIXES ".a.${_NCCL_VERSION}" ${CMAKE_FIND_LIBRARY_SUFFIXES})
+  endif()
+else()
+  SET(NCCL_LIBNAME "nccl")
+  if (_NCCL_VERSION)  # Prefer the versioned library if a specific NCCL version is specified
+    set(CMAKE_FIND_LIBRARY_SUFFIXES ".so.${_NCCL_VERSION}" ${CMAKE_FIND_LIBRARY_SUFFIXES})
+  endif()
+endif()
+
+# Read version from header
+if(EXISTS "${NCCL_INCLUDE_DIRS}/nccl.h")
+  file(READ ${NCCL_INCLUDE_DIRS}/nccl.h NCCL_HEADER_CONTENTS)
+endif()
+if(NCCL_HEADER_CONTENTS)
+  string(REGEX MATCH "define NCCL_MAJOR * +([0-9]+)"
+               _NCCL_VERSION_MAJOR "${NCCL_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define NCCL_MAJOR * +([0-9]+)" "\\1"
+               _NCCL_VERSION_MAJOR "${_NCCL_VERSION_MAJOR}")
+  string(REGEX MATCH "define NCCL_MINOR * +([0-9]+)"
+               _NCCL_VERSION_MINOR "${NCCL_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define NCCL_MINOR * +([0-9]+)" "\\1"
+    _NCCL_VERSION_MINOR "${_NCCL_VERSION_MINOR}")
+  string(REGEX MATCH "define NCCL_PATCH * +([0-9]+)"
+    _NCCL_VERSION_PATCH "${NCCL_HEADER_CONTENTS}")
+  string(REGEX REPLACE "define NCCL_PATCH * +([0-9]+)" "\\1"
+    _NCCL_VERSION_PATCH "${_NCCL_VERSION_PATCH}")
+  if(NOT _NCCL_VERSION_MAJOR)
+    set(_NCCL_VERSION "?")
+  else()
+    set(_NCCL_VERSION "${_NCCL_VERSION_MAJOR}.${_NCCL_VERSION_MINOR}.${_NCCL_VERSION_PATCH}")
+  endif()
+endif()
+
+find_library(NCCL_LIBRARIES
+  NAMES ${NCCL_LIBNAME}
+  HINTS
+  ${NCCL_LIB_DIR}
+  ${CUDA_TOOLKIT_ROOT}
+  $ENV{CUDA_PATH}
+  $ENV{CUDNN_ROOT_DIR}
+  $ENV{CUDA_TOOLKIT_ROOT_DIR}
+  $ENV{NCCL}
+  /usr/lib/x86_64-linux-gnu/
+  PATH_SUFFIXES
+  lib
+  lib64
+)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(NCCL
+  REQUIRED_VARS NCCL_INCLUDE_DIRS NCCL_LIBRARIES
+  VERSION_VAR   _NCCL_VERSION)
+
+if(NCCL_FOUND)  # obtaining NCCL version and some sanity checks
+  message(STATUS "Found NCCL ${_NCCL_VERSION} (include: ${NCCL_INCLUDE_DIRS}, library: ${NCCL_LIBRARIES})")
+  mark_as_advanced(NCCL_ROOT_DIR NCCL_INCLUDE_DIRS NCCL_LIBRARIES NCCL_VERSION)
+endif()

externals/vcpkg/ports/nccl/portfile.cmake

@@ -0,0 +1,20 @@
+
+# Find NCCL. We can use FindNCCL directly since it doesn't call any functions
+# that are disallowed in CMake script mode
+set(MINIMUM_NCCL_VERSION "2.4.6.1")
+set(NCCL_PREV_MODULE_PATH ${CMAKE_MODULE_PATH})
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
+find_package(NCCL ${MINIMUM_NCCL_VERSION})
+set(CMAKE_MODULE_PATH ${NCCL_PREV_MODULE_PATH})
+
+# Download or return
+if(NCCL_FOUND)
+  message(STATUS "Using NCCL ${_NCCL_VERSION} located on system.")
+  set(VCPKG_POLICY_EMPTY_PACKAGE enabled)
+else()
+  message(FATAL_ERROR "Please install NCCL using your system package manager (the same way you installed CUDA). For example: apt install libnccl2 libnccl-dev.")
+endif()
+
+file(INSTALL "${CURRENT_PORT_DIR}/FindNCCL.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
+configure_file("${CURRENT_PORT_DIR}/vcpkg-cmake-wrapper.cmake" "${CURRENT_PACKAGES_DIR}/share/${PORT}/vcpkg-cmake-wrapper.cmake" @ONLY)
+file(INSTALL "${CURRENT_PORT_DIR}/usage" DESTINATION ${CURRENT_PACKAGES_DIR}/share/${PORT})

externals/vcpkg/ports/nccl/usage

@@ -0,0 +1,5 @@
+The package nccl provides CMake variables:
+
+    find_package(NCCL REQUIRED)
+    target_link_libraries(main PRIVATE ${NCCL_LIBRARIES})
+    target_include_directories(main PRIVATE ${NCCL_INCLUDE_DIRS})

externals/vcpkg/ports/nccl/vcpkg-cmake-wrapper.cmake

@@ -0,0 +1,6 @@
+set(NCCL_PREV_MODULE_PATH ${CMAKE_MODULE_PATH})
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
+
+_find_package(${ARGS})
+
+set(CMAKE_MODULE_PATH ${NCCL_PREV_MODULE_PATH})

externals/vcpkg/ports/nccl/vcpkg.json

@@ -0,0 +1,10 @@
+{
+  "name": "nccl",
+  "version": "2.4.6",
+  "port-version": 2,
+  "description": "Optimized primitives for collective multi-GPU communication.",
+  "supports": "linux & x64",
+  "dependencies": [
+    "cuda"
+  ]
+}