early-access version 2853

externals/vcpkg/ports/sdl2-ttf/CMakeLists.txt

@@ -0,0 +1,52 @@
+cmake_minimum_required(VERSION 3.0)
+project(SDL2_TTF C)
+
+find_path(SDL_INCLUDE_DIR SDL2/SDL.h)
+find_package(SDL2 CONFIG REQUIRED)
+find_package(Freetype REQUIRED)
+
+add_library(SDL2_ttf SDL_ttf.c version.rc)
+
+set_target_properties(SDL2_ttf PROPERTIES DEFINE_SYMBOL DLL_EXPORT)
+target_include_directories(SDL2_ttf PRIVATE ${SDL_INCLUDE_DIR}/SDL2 ${FREETYPE_INCLUDE_DIRS})
+target_link_libraries(SDL2_ttf SDL2::SDL2 ${FREETYPE_LIBRARIES})
+
+install(TARGETS SDL2_ttf
+    EXPORT SDL2_ttf
+    RUNTIME DESTINATION bin
+    ARCHIVE DESTINATION lib
+    LIBRARY DESTINATION lib)
+
+INSTALL(EXPORT SDL2_ttf
+    DESTINATION "share/sdl2-ttf"
+    FILE sdl2-ttf-config.cmake
+    NAMESPACE SDL2::
+)
+
+set(prefix "")
+set(exec_prefix [[${prefix}]])
+set(libdir [[${prefix}/lib]])
+set(includedir [[${prefix}/include]])
+set(PACKAGE "SDL2_ttf")
+file(READ "SDL_ttf.h" header_contents)
+#    #define SDL_TTF_MAJOR_VERSION 2
+#    #define SDL_TTF_MINOR_VERSION 0
+#    #define SDL_TTF_PATCHLEVEL    5
+string(REGEX MATCH "define *SDL_TTF_MAJOR_VERSION *([0-9]+)" _ "${header_contents}")
+set(VERSION ${CMAKE_MATCH_1})
+string(REGEX MATCH "define *SDL_TTF_MINOR_VERSION *([0-9]+)" _ "${header_contents}")
+string(APPEND VERSION ".${CMAKE_MATCH_1}")
+string(REGEX MATCH "define *SDL_TTF_PATCHLEVEL *([0-9]+)" _ "${header_contents}")
+string(APPEND VERSION ".${CMAKE_MATCH_1}")
+set(SDL_VERSION 0.0)
+configure_file(SDL2_ttf.pc.in "${CMAKE_CURRENT_BINARY_DIR}/SDL2_ttf.pc" @ONLY)
+file(APPEND "${CMAKE_CURRENT_BINARY_DIR}/SDL2_ttf.pc" "Requires.private: freetype2")
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/SDL2_ttf.pc DESTINATION lib/pkgconfig)
+
+if(NOT DEFINED SDL_TTF_SKIP_HEADERS)
+    install(FILES SDL_ttf.h DESTINATION include/SDL2)
+endif()
+
+message(STATUS "Link-time dependencies:")
+message(STATUS "  " SDL2::SDL2)
+message(STATUS "  " ${FREETYPE_LIBRARIES})

externals/vcpkg/ports/sdl2-ttf/portfile.cmake

@@ -0,0 +1,31 @@
+set(VERSION 2.0.15)
+
+vcpkg_download_distfile(ARCHIVE
+    URLS "https://www.libsdl.org/projects/SDL_ttf/release/SDL2_ttf-${VERSION}.tar.gz"
+    FILENAME "SDL2_ttf-${VERSION}.tar.gz"
+    SHA512 30d685932c3dd6f2c94e2778357a5c502f0421374293d7102a64d92f9c7861229bf36bedf51c1a698b296a58c858ca442d97afb908b7df1592fc8d4f8ae8ddfd
+)
+
+vcpkg_extract_source_archive_ex(
+    OUT_SOURCE_PATH SOURCE_PATH
+    ARCHIVE ${ARCHIVE}
+    REF ${VERSION}
+)
+
+file(COPY ${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt DESTINATION ${SOURCE_PATH})
+
+vcpkg_configure_cmake(
+    SOURCE_PATH ${SOURCE_PATH}
+    PREFER_NINJA
+    OPTIONS_DEBUG
+        -DSDL_TTF_SKIP_HEADERS=ON)
+
+vcpkg_install_cmake()
+vcpkg_copy_pdbs()
+vcpkg_fixup_cmake_targets()
+vcpkg_fixup_pkgconfig()
+
+file(REMOVE_RECURSE ${CURRENT_PACKAGES_DIR}/debug/share)
+
+file(COPY ${SOURCE_PATH}/COPYING.txt DESTINATION ${CURRENT_PACKAGES_DIR}/share/sdl2-ttf)
+file(RENAME ${CURRENT_PACKAGES_DIR}/share/sdl2-ttf/COPYING.txt ${CURRENT_PACKAGES_DIR}/share/sdl2-ttf/copyright)

externals/vcpkg/ports/sdl2-ttf/vcpkg.json

@@ -0,0 +1,11 @@
+{
+  "name": "sdl2-ttf",
+  "version-string": "2.0.15",
+  "port-version": 5,
+  "description": "A library for rendering TrueType fonts with SDL",
+  "homepage": "https://www.libsdl.org/projects/SDL_ttf/",
+  "dependencies": [
+    "freetype",
+    "sdl2"
+  ]
+}