early-access version 1255

externals/dynarmic/CMakeModules/CreateDirectoryGroups.cmake

@@ -0,0 +1,17 @@
+# This function should be passed a name of an existing target. It will automatically generate
+# file groups following the directory hierarchy, so that the layout of the files in IDEs matches the
+# one in the filesystem.
+function(create_target_directory_groups target_name)
+    # Place any files that aren't in the source list in a separate group so that they don't get in
+    # the way.
+    source_group("Other Files" REGULAR_EXPRESSION ".")
+
+    get_target_property(target_sources "${target_name}" SOURCES)
+
+    foreach(file_name IN LISTS target_sources)
+        get_filename_component(dir_name "${file_name}" PATH)
+        # Group names use '\' as a separator even though the entire rest of CMake uses '/'...
+        string(REPLACE "/" "\\" group_name "${dir_name}")
+        source_group("${group_name}" FILES "${file_name}")
+    endforeach()
+endfunction()

externals/dynarmic/CMakeModules/DetectArchitecture.cmake

@@ -0,0 +1,16 @@
+include(CheckSymbolExists)
+function(detect_architecture symbol arch)
+    if (NOT DEFINED ARCHITECTURE)
+        set(CMAKE_REQUIRED_QUIET 1)
+        check_symbol_exists("${symbol}" "" ARCHITECTURE_${arch})
+        unset(CMAKE_REQUIRED_QUIET)
+
+        # The output variable needs to be unique across invocations otherwise
+        # CMake's crazy scope rules will keep it defined
+        if (ARCHITECTURE_${arch})
+            set(ARCHITECTURE "${arch}" PARENT_SCOPE)
+            set(ARCHITECTURE_${arch} 1 PARENT_SCOPE)
+            add_definitions(-DARCHITECTURE_${arch}=1)
+        endif()
+    endif()
+endfunction()

externals/dynarmic/CMakeModules/FindUnicorn.cmake

@@ -0,0 +1,37 @@
+# Exports:
+#
+# Variables:
+#  LIBUNICORN_FOUND
+#  LIBUNICORN_INCLUDE_DIR
+#  LIBUNICORN_LIBRARY
+#
+# Target:
+#  Unicorn::Unicorn
+#
+
+find_path(LIBUNICORN_INCLUDE_DIR
+          unicorn/unicorn.h
+          HINTS $ENV{UNICORNDIR}
+          PATH_SUFFIXES include)
+
+find_library(LIBUNICORN_LIBRARY
+             NAMES unicorn
+             HINTS $ENV{UNICORNDIR})
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Unicorn DEFAULT_MSG LIBUNICORN_LIBRARY LIBUNICORN_INCLUDE_DIR)
+
+if (UNICORN_FOUND)
+    set(THREADS_PREFER_PTHREAD_FLAG ON)
+    find_package(Threads REQUIRED)
+    unset(THREADS_PREFER_PTHREAD_FLAG)
+
+    add_library(Unicorn::Unicorn UNKNOWN IMPORTED)
+    set_target_properties(Unicorn::Unicorn PROPERTIES
+        IMPORTED_LOCATION ${LIBUNICORN_LIBRARY}
+        INTERFACE_INCLUDE_DIRECTORIES ${LIBUNICORN_INCLUDE_DIR}
+        INTERFACE_LINK_LIBRARIES Threads::Threads
+    )
+endif()
+
+mark_as_advanced(LIBUNICORN_INCLUDE_DIR LIBUNICORN_LIBRARY)